Willkommen auf schweda.net | EN | DE
 
 
 
 
 
Momentan angezeigt werden nur Einträge, welche für die Dynamics AX-Version »Axapta 2.5« relevant sind. Filter entfernen

RSS-Feed dieser Version

Wer schon einmal die Parameter einer Methode erweitern musste, kennt vielleicht das Problem: Wenn man Glück hat kann man seinen neuen Parameter am Ende einfügen und mit einem Default-Wert vorbelegen.

Hat man nicht ganz so viel Glück und muss entweder der Parameter zwischen den vorhandenen einbauen oder darf/kann keinen Default-Wert angeben so muss man den gesamten AOT nach den Aufrufen dieser Methode durchsuchen (die Querverweise helfen hier enorm) und diese entsprechend anpassen.

Aufgrund dieser Problematik gehe ich bei meinen Methoden nun oft den Weg, daß ich nur einen einzigen Parameter einfüge, und zwar vom Typ einer - nennen wir sie einfach einmal DataContract-Klasse.

DataContracts sind dem einen oder anderen vielleicht aus dem SSRS-Umfeld bekannt, aber die selbe Logik kann ich auch in vielen anderen Situationen anwenden.

So sieht eine solche DataContract-Klasse beispielweise wie folgt aus:

classDeclaration MyDataContract
{
    ItemId itemId;     Qty qty;
}

 

Public ItemId parmItemId(ItemId _itemId = itemId)
{
    itemId = _itemId;
    return itemId;
}

 

Public Qty parmQty(Qty _qty = qty)
{
    qty = _qty;
    return qty;
}


Eine Methode könnte dann wie folgt aussehen:

Public void myMethod(MyDataContract _dataContract)
{
    // … do something…
    info(_dataContract.parmItemId());
}


Aufrufen muss ich eine solche Methode so:

MyDataContract dataContract;
dataContract = new MyDataContract();
dataContract.parmItemId("A1000");
dataContract.parmQty(123);

Object.myMethod(dataContract);


Kommt nun später ein neuer Parameter hinzu, muss ich den lediglich entsprechend in der DataContract-Klasse einfügen und die Logik in der Methode erweitern. Die Methodenaufrufe können u.U. so bleiben wie sie waren, lediglich die Aufrufe wo die geänderten Parameter berücksichtigt werden müssen, müssen angepasst werden.

Und zu guter Letzt kann ich solche DataContract-Klassen natürlich für mehrere Methoden verwenden.
 

 


In Dynamics AX können unterschiedliche (Fehler-)Meldungen auftreten, die meisten kommen von der Applikation, es gibt aber auch Meldungen, die vom AX-Client ausgegeben werden.

Leider sind nicht alle Meldungen so sprechend, daß man (als Entwickler) sofort weiß, was nun zu tun ist. Deshalb gibt es, je nachdem um welche Art von Fehlermeldung es sich handelt, unterschiedliche Herangehensweisen, wie man die Ursache der Meldung findet.

Meldung über das Infolog der Applikation

Screenshot InfologBei manchen Meldungen genügt ein Doppelklick auf die Meldung im Infolog und man landet im Code, welcher die Meldung geworfen hat (vorausgesetzt man befindet sich als Benutzer gerade im Entwicklungsmodus).


Nachstehend ein kurzer Job, mit dessen Hilfe man AOT-Elemente zu einem bestehenden Shared Project hinzufügen kann.

static void AddNodeToSharedProject(Args _args)
{
    projectNode projectNode;
    TreeNode treeNode;
    #AOT
    #AOTExport

    projectNode    = infolog.projectRootNode();
    projectNode    = projectNode.AOTfindChild(#expProjectShared);
    projectNode    = projectNode.AOTfindChild('MyProject');
   
    // Add objects
    treenode = TreeNode::findNode(#TablesPath+'\\'+tableid2name(tablenum(CustGroup)));
    projectNode.addNode(treenode);

    treenode = TreeNode::findNode(#TablesPath+'\\'+tableid2name(tablenum(VendGroup)));
    projectNode.addNode(treenode);
   
    treenode = TreeNode::findNode(#ClassesPath+'\\'+classStr(PriceDisc));
    projectNode.addNode(treenode);
}

Das geänderte Projekt sieht beispielsweise wie folgt aus:

Screenshot


Das Beispiel listet beispielsweise nur aktive Stücklistenpositionen (Tabelle BOM) auf (aktiv über die Felder FromDate und ToDate). Lässt man den zweiten Parameter des Makros leer (dateNull()), so werden alle Stücklistenpositionen gelistet.

static void useMacroInSelectStatement(Args _args)
{
    bom bom;
    date emptyDate;
   
    // parameters: %1 = table instance, %2 date, %3 empty date value
    #localmacro.bomDateFilter
        && ( %2 == dateNull() || (
            ((%1.FromDate <= %2) && (%1.ToDate >= %2)) ||
            ((%1.FromDate == %3) && (%1.ToDate == %3)) ||
            ((%1.FromDate <= %2) && (%1.ToDate == %3)) ||
            ((%1.FromDate == %3) && (%1.ToDate >= %2))
            ))
    #endMacro
    ;
   
    while select bom
    where bom.ItemId == '123'
    #bomDateFilter(bom, systemDateGet(), emptyDate)
    {
        info(bom.bomid);
    }
}

 


Mir wurde diese Frage vor kurzem selbst gestellt und konnte diese allerdings nur zum Teil beantworten.

Ich wusste aber noch, daß ich schon einmal eine Seite gesehen hatte, wo dies genau erklärt wird. Aber ich wusste weder noch wo, noch konnte ich sie über diverse Suchmaschinen finden.

Aber in alten Unterlagen fand ich die Quelle dann doch, der Trick um die Quelle auch mit Google und Konsorten zu finden ist, mit dem altem Namen von Microsoft Dynamics AX - Axapta danach zu suchen!

Tut man dies, so findet man rasch folgende Seite:

http://www.axaptapedia.com/index.php?title=Lookups


Im folgenden ein Beispiel, wie man bei einer FormDataSource einen QueryBuildRange aufbaut, welcher nur tagesaktuelle Datensätze anzeigt.

Im Beispiel enthält unsere FormDataSource namens DataSourceName zwei Datumsfelder namens FromDate und ToDate und es sollen abhängig von einer Checkbox nur Datensätze angezeigt werden, die "heute" gültig sind.

public void applyFilter()
{
    queryBuildRange qbr;

    qbr = sysQuery::findOrCreateRange(DataSourceName_ds.queryBuildDataSource(), fieldNum(DataSourceName, recId));

    if( !ShowExpiredCheckBox.checked())
    {
        qbr.value(strfmt('('+
                         '((%5.%2 <= %1) && (%5.%3 >= %1)) || ' +
                         '((%5.%2 == %4) && (%5.%3 == %4)) || ' +
                         '((%5.%2 <= %1) && (%5.%3 == %4)) || ' +
                         '((%5.%3 >= %1) && (%5.%2 == %4)) ' +
                         ')',
                                Date2StrXpp(systemDateGet()),
                                fieldstr(DataSourceName, FromDate),
                                fieldstr(DataSourceName, ToDate),
                                Date2StrXpp(dateNull()),
                                tableId2name(tableNum(DataSourceName))));
    }
    else
    {
        qbr.value(SysQuery::valueUnlimited());
    }
}

Der Aufruf obiger Methode kann beispielsweise in der executeQuery() der Datasource erfolgen.


In Dynamics AX kann man selbstverständlich auch auf die Zwischenablage zugreifen, ein kurzes Codebeispiel dazu im folgenden. Funktioniert übrigens zumindest seit Axpata 2.5.

static void useClipboard(Args _args)
{
    textBuffer  textBuffer = new textBuffer();
    ;    
    // Write to clipboard

    textBuffer.appendText('Hello world!');
    textBuffer.toClipboard();

    // Read from clipboard
    textBuffer.fromClipboard();
    info(textBuffer.getText());
}

Seiten 1 2 » 

 

 
Kategorien / Themen
Feeds
RSS RSS-Feed
Atom Atom-Feed
 
 
Beiträge des aktuellen Monats
Juni 2017
MoDiMiDoFrSaSo
 1234
567891011
12131415161718
19202122232425
2627282930 
 
 
© 2006-2016 Heinz Schweda | Impressum | Kontakt | English version (BETA) | Mobile Version
Diese Webseite verwendet Cookies, um Benutzern einen besseren Service anzubieten. Wenn Sie weiterhin auf der Seite bleiben, stimmen Sie der Verwendung von Cookies zu. Mehr dazu