AX 2012: Dimensionen einer Position einer Allgemeines Erfassung per X++ auslesen

Wenn man bei einer Position einer Allgemeinen Erfassung, welche gegen ein Sachkonto/Hauptkonto bucht, per X++ die eingetragenen Dimensionen auslesen möchte, kann der folgende Code möglicherweise hilfreich sein.

Position einer Allgemeinen Erfassung

static void getLedgerDimensionData(Args _args) 
{ 
    LedgerJournalTrans ledgerJournalTrans; 

    void getDimensionsFromDefaultDimension(RecId _dimensionrecid) 
    { 
        DimensionAttributeValueSet dimensionAttributeValueSet; 
        DimensionAttributeValueSetItem dimensionAttributeValueSetItem; 
        DimensionAttributeValue         dimensionAttributeValue; 
        DimensionAttribute dimensionAttribute; 
        Common dimensionValueEntity; 

        dimensionAttributeValueSet = DimensionAttributeValueSet::find(_dimensionrecid); 

        // Find all of the 'value set items' linked against the 'value set' 
        while select dimensionAttributeValueSetItem 
            where   dimensionAttributeValueSetItem.DimensionAttributeValueSet == dimensionAttributeValueSet.RecId 
        { 
            // Find the dimension 'value' (DimensionAttributeValue) that the set item points to. 
            dimensionAttributeValue = DimensionAttributeValue::find(dimensionAttributeValueSetItem.DimensionAttributeValue); 

            // Find the underlying attribute. 
            dimensionAttribute = DimensionAttribute::find(dimensionAttributeValue.DimensionAttribute); 

            // Use the helper class to obtain a reference to the underlying entity (can be anything) 
            dimensionValueEntity = DimensionDefaultingControllerBase::findBackingEntityInstance( 
                curext(), 
                dimensionAttribute, 
                dimensionAttributeValue.EntityInstance); 

            info(strFmt("%1: %2 - %3", dimensionAttribute.Name, 
                                       dimensionAttributeValue.getValue(), 
                                       dimensionAttributeValue.getName() 
                                       )); 
        } 
    } 
    ; 

    while select ledgerJournalTrans 
        where ledgerJournalTrans.JournalNum == '000151_010' 
    { 
        // Get main account data 
        info(strFmt("Main account display value: %1", DimensionAttributeValueCombination::find(ledgerJournalTrans.LedgerDimension).DisplayValue)); 

        if(MainAccount::find(DimensionAttributeValueCombination::find(ledgerJournalTrans.LedgerDimension).MainAccount)) 
        { 
            info(strFmt("Main account: %1 - %2", MainAccount::find(DimensionAttributeValueCombination::find(ledgerJournalTrans.LedgerDimension).MainAccount).MainAccountId, 
                                                 MainAccount::find(DimensionAttributeValueCombination::find(ledgerJournalTrans.LedgerDimension).MainAccount).Name)); 

            info(strFmt("Account structure: %1", DimensionStorage::getAccountStructureFromLedgerDimension(ledgerJournalTrans.LedgerDimension).Name)); 
        } 

        // Get dimension values 
        setPrefix("Dimension values"); 

        getDimensionsFromDefaultDimension(DimensionStorage::getDefaultDimensionFromLedgerDimension(ledgerJournalTrans.LedgerDimension)); 
    } 
}

Als Ergebnis des obigen Jobs wird ein Infolog ausgegeben.

Infolog

Dieser Beitrag bezieht sich auf die Version:
Dynamics AX 2012

Kommentar hinzufügen
 
 

 

Dies ist ein Beitrag aus der Serie »Dynamics AX 2012 - Finanzdimensionen«

In Dynamics AX 2012 hat sich die Handhabung von Finanzdimensionen stark verändert. Und zwar sowohl auf der Oberfläche als auch das dahinterliegende Datenmodell. Wo früher noch ein Feld - meist mit dem Namen Dimension - vom Typ Array in einer Tabelle zu finden war, so findet man nun stattdessen ein von RecId abgeleitetes Feld namens DefaultDimension (o.ä.).

In dieser Serie möchte ich speziell auf diese Änderungen eingehen und das eine oder andere Stück Code präsentieren.

Alle Beiträge dieser Serie anzeigen

RSS-Feed dieser Blogserie


 

 
 
 
Beiträge des aktuellen Monats
Dezember 2019
MoDiMiDoFrSaSo
 1
2345678
9101112131415
16171819202122
23242526272829
3031 
 
© 2006-2019 Heinz Schweda | Impressum | Kontakt | English version | Mobile Version
Diese Webseite verwendet Cookies, um Benutzern einen besseren Service anzubieten. Wenn Sie weiterhin auf der Seite bleiben, stimmen Sie der Verwendung von Cookies zu.  Mehr dazu