Blog von Heinz Schweda

Shared Project mit X++ erstellen II

2010-08-05T19:15:44Z

In einem früheren Beitrag habe ich ja hier schon einen Job veröffentlicht, mit dessen Hilfe man sich per X++ ein Shared Project erstellen kann. Basierend auf der neu entdeckten Funktion selectMultiple habe ich diesen nun etwas erweitert, der Benutzer hat mit dessen Hilfe nun die Möglichkeit, ein Shared Project zu erstellen und dabei für die aktuell benötigten Datentypen eigene Gruppenknoten innerhalb dieses Projektes zu erstellen.

static void CreateSharedProjectUsingSelectMultiple(Args _args)

{

    DictEnum            DictEnum;

    container           conValues;

    container           conSelectedValues;

    container           conSelectMultiple;

    int                 i;

    projectNode         projectNode;

    projectGroupNode    projectGroupNode;

    projectNode         myProjectNode;

    treeNodeName        nameOfProject;

    groupNodeType       groupNodeType;

    treeNodeName        groupNodeName;

    dialog              dialog;

    dialogField         dfProjectName;

    #AOTExport

    ;

    // Create dialog

    dialog = new dialog();

    dfProjectName = dialog.addFieldValue(typeId(treeNodeName), "NameOfproject", "Name of project");

    if( !dialog.run())

    {

        return;

    }

    nameOfProject = dfProjectName.value() ? dfProjectName.value() : "Unknown";

    // Add available values to container

    DictEnum = new DictEnum(enumName2Id(identifierStr(GroupNodeType)));

    for(i=1;i
    {

        conValues = conIns(conValues, conLen(conValues)+1, [DictEnum.index2Label(i), i, false]);

    }

    // Call selectMultiple

    conSelectMultiple = selectMultiple("Please select", "Please select the needed project-groups", conValues);

    conSelectedValues = conPeek(conSelectMultiple, 2);

    if( !conPeek(conSelectMultiple, 1))

    {

        return;

    }

    // Create shared project

    projectNode    = infolog.projectRootNode();

    projectNode    = projectNode.AOTfindChild(#expProjectShared);

    myProjectNode  = projectNode.AOTfindChild(nameOfProject);

    if( !myProjectNode)

    {

        myProjectNode = projectNode.AOTadd(nameOfProject);

        myProjectNode.AOTsave();

    }

    myProjectNode     = myProjectNode.getRunNode();

    if(conPeek(conSelectMultiple, 1))

    {

        for (i=1; i<=conLen(conSelectedValues); i++)

        {

            groupNodeName = DictEnum.index2Label(conPeek(conSelectedValues, i));

            projectGroupNode = myProjectNode.AOTfindChild(groupNodeName);

            if( !projectGroupNode)

            {

                myProjectNode.AOTadd(groupNodeName);

                projectGroupNode = myProjectNode.AOTfindChild(groupNodeName);

                projectGroupNode.projectGroupType(DictEnum.name2Value(groupNodeName));

                myProjectNode.AOTsave();

            }

        }

    }

    projectGroupNode.AOTsave();

    myProjectNode.AOTsave();

    myProjectNode.AOTrefresh();

    myProjectNode.AOTrun();

}

Obiger Code funktioniert meines Wissens nach in Dynamics AX 4.0 und Dynamics AX 2009.

selectMultiple und selectSingle

2010-08-05T19:23:36Z

Beim Stöbern in den vorgefertigten Methoden in der global-Klasse bin ich auf zwei Funktionen gestossen, die ich schon früher das eine oder andere Mal gebraucht hätte: selectMultiple und selectSingle.

Was können diese Funktionen? Man übergibt Ihnen einen Container mit möglichen Werten und als Rückgabewert erhält man ebenfalls einen Container mit den vom Benutzer ausgewählten Werten. Dazwischen wird ein Dialog generiert, der nicht benutzerfreundlicher sein könnte, wie ich finde.

Obiger Dialog wurde über den nachstehenden Job erzeugt.

static void selectMultiple(Args _args)

{

    container   conValues;

    container   conSelectedValues;

    container   conSelectMultiple;

    int         i;

    ;

    conValues = conIns(conValues, conLen(conValues)+1, ["Dynamics AX 3.0\nAlias Microsoft Business Solutions Axapta 3.0", "30", false]);

    conValues = conIns(conValues, conLen(conValues)+1, ["Dynamics AX 4.0", "40", false]);

    conValues = conIns(conValues, conLen(conValues)+1, ["Dynamics AX 2009", "50", true]);

    conSelectMultiple = selectMultiple("Bitte wählen Sie aus", "Bitte wählen Sie Ihre verwendeten Dynamics AX-Versionen aus", conValues, ["Version", "Bemerkung"]);

    conSelectedValues = conPeek(conSelectMultiple, 2);

    if(conPeek(conSelectMultiple, 1))

    {

        for (i=1; i<=conLen(conSelectedValues); i++)

        {

            info(conPeek(conSelectedValues, i));

        }

    }

}

selectSingle funktioniert vom Prinzip her genauso, mit dem einzigen Unterschied daß der Benutzer nur einen Wert auswählen kann.

In einem Job, mit dessen Hilfe man per X++ ein Shared Project erstellt, habe ich mein neues Wissen auch schon angewendet.

Feldwert eines aufrufenden Objektes ermitteln

2010-07-19T09:17:07Z

In vielen Objekten sieht man Kontrukte wie das folgende, die dazu dienen, einen Wert aus dem aufrufenden Datensatz zu ermitteln.

if (element.args() && element.args().record())

{

    switch (element.args().dataset())

    {

        case tablenum(PurchLine)    :

            itemIdCaller = element.args().record().(fieldNum(purchLine, ItemId));

            break;

        case tablenum(SalesLine)    :

            itemIdCaller = element.args().record().(fieldNum(SalesLine, ItemId));

            break;

        case tablenum(SalesQuotationLine)    :

            itemIdCaller = element.args().record().(fieldNum(SalesQuotationLine, ItemId));

            break;

    }

}

Einfacher geht’s mit unten dem stehenden Stückchen Code! Der grosse Vorteil von diesem ist, daß wann immer man das Objekt von einem Datensatz aus aufruft, der ein Feld namens itemId enthält, die Logik abgearbeitet wird ohne daß man jede Tabelle einzeln im switch-Statement berücksichtigen muss.

if (element.args() && element.args().record())

{

    sysDictTable = new sysDictTable(element.args().dataset());

    if(sysDictTable.fieldName2Id('itemId'))

    {

        itemIdCaller = element.args().record().(sysDictTable.fieldName2Id('itemId'));

    }

}

Liste aller Felder einer Tabelle ausgeben

2010-07-24T10:59:21Z

Unlängst benötigte ich eine Liste aller Felder einer Tabelle mit deren Datentypen. Dafür habe ich mir den folgenden Job - im Beispiel für die Tabelle custGroup - geschrieben:

static void listAllFields4Table(Args _args)

{

    dictTable   dictTable = new dictTable(tableNum(custGroup));

    int         currFieldId = 0;

    counter     c = 0;

    dictField   dictField;

    counter     a = 0;

    common      common;

    str         enumName;

    ;

    common = DictTable.makeRecord();

    setPrefix(strFmt("Fields of table %1",  tableId2name(common.TableId)));

    currFieldId = 0;

    c = 0; 

    do

    {

        currFieldId = dictTable.fieldNext(currFieldId); 

        if(currFieldId != 0)

        {

            dictField = new dictField(common.TableId, currFieldId); 

            if(dictField.arraySize() == 1)

            {

                info(   strFmt("%1: %2 [%3%4]",

                        dictTable.fieldName(currFieldId),

                        dictField.label(),

                        dictField.baseType(),

                        dictField.enumId() ? strFmt(" %1", enumId2Name(dictField.enumId())) : "")

                     );

            }

            else if(dictField.arraySize() > 1)

            {

                for(a=1;a<=dictField.arraySize();a++)

                {

                    info(   strFmt("%1 [%2]: %3 [%4]",

                            dictTable.fieldName(currFieldId),

                            a,

                            dictField.label(),

                            dictField.baseType())

                         );

                }

            }

        }

        c++;

    }

    while (c < dictTable.fieldCnt());

}

Das Ergebnis dieses Jobs sieht wie folgt aus:

Pr�fungen durchf�hren beim/vor dem Schliessen eines Formulares

2010-07-20T13:39:44Z

Möchte/muß man beim bzw. vor dem Schliessen eines Formulares etwas tun, z.B. Prüfungen durchführen, so stellt Dynamics AX dafür einige Methoden zur Verfügung, die in einer bestimmten Reihenfolge abgearbeitet werden. Da ich selbst mir diese Reihenfolge nicht merke, habe ich sie hier kurz notiert.

Beim Schliessen eines Formulares über einen OK-Commandbutton:

closeOK
canClose
close

Beim Schliessen eines Formulares über einen CANCEL-Commandbutton:

closeCancel
canClose
close

Beim Schliessen eines Formulares über "das rote X" bzw. der ESC-Taste:

canClose
close

Bei einer Lookup-Form verhält es sich etwas anders:

Beim Schliessen eines Formulares über einen OK-Commandbutton:

closeSelect
closeOK
canClose
close

Beim Schliessen eines Formulares über einen CANCEL-Commandbutton:

closeSelect
closeOK
canClose
close

Beim Schliessen eines Formulares über "das rote X" bzw. der ESC-Taste:

canClose
close

Daraus ergibt sich, daß die optimale Methode für Prüfungen die canClose-Methode ist.

Hier nun noch ein kurzer Job, der ein Formular öffnet und nach dessen Schliessen ermittelt, wie das Formular geschlossen wurde:

static void OpenForm(Args _args)

{

    FormRun form = null;

    Args    formParams = new Args();

    ; 

    formParams.name(formStr(CustTable));

    form = classFactory.formRunClass(formParams);

    form.init();

    form.run();

    form.wait();

    if(form.closed())

    {

        setPrefix("Form was closed.");

        if(form.closedOk())

        {

            info("Form was closed by OK-Button.");

        }

        else if(form.closedCancel())

        {

            info("Form was closed by CANCEL-Button.");

        }

        else

        {

            info("Form was closed by CLOSE-Button.");

        }

    }

}

Auslesen von HTML-Quelltext in Dynamics AX 2009

2010-08-12T19:33:07Z

Vor kurzem wurde ich gefragt, wie man denn in Dynamics AX 2009 den HTML-Quelltext einer Webseite ausliest. Bitteschön...

static void GetHTMLSourceCode(Args _args)

{

    CLRObject                   castObject      = null;

    System.Net.HttpWebRequest   request         = null;

    System.Net.HttpWebResponse  response        = null;

    System.IO.StreamReader      streamReader    = null;

    System.Text.Encoding        encoding        = null; 

    url                         url = "http://www.yourdomain.com/yoursite.html";

    ;

    new InteropPermission(InteropKind::ClrInterop).assert();

    castObject = System.Net.WebRequest::Create(url);

    request = castObject;

    response = request.GetResponse();

    encoding = System.Text.Encoding::get_UTF8();

    streamReader = new System.IO.StreamReader(response.GetResponseStream(), encoding);

    info(streamReader.ReadToEnd());

}

Label in einer bestimmten Sprache auslesen

2010-08-14T15:23:48Z

Um in X++ ein Label in einer ganz bestimmten Sprache auszugeben, nutzt man am besten die Methode labelId2String2 der SysLabel-Klasse:

info(any2str(SysLabel::labelId2String2(literalStr("@SYS14204"),"de-at")));

AxInventTable: Artikel per Code anlegen in Dynamics AX 2009

2010-05-15T20:10:16Z

Um einen Artikel in Dynamics AX 2009 anzulegen kann man sich - wie schon in früheren Versionen - der Klasse axInventTable bedienen. Dies Klasse hat den grossen Vorteil, daß sie sich auch um jene Tabellen kümmert, die neben der inventTable befüllt werden müssen, also die drei Datensätze in der inventTableModule und jenen in der InventItemLocation, sodaß der Artikel sofort in der Form InventTable aufscheint.

static void createItemUsingAxInventTable(Args _args)

{

    axInventTable axInventTable;

    ;

    axInventTable = axInventTable::construct();

    axInventTable.parmItemId('NewItemId');

    axInventTable.save();

}

Etwas sollte man bei Verwendung der Klasse allerdings berücksichtigen: Obiger Job erstellt den Artikel, ohne eventuelle Pflichtfelder wie z.B. die Artikelgruppe zu befüllen. Das aber auch nur, wenn es keine Datensatzvorlage vom Typ Unternehmensvorlage gibt. Gibt es eine solche Standardvorlage für den Artikelstamm, so nutzt AX diese!

Firmwareupgrade beim HDC-350

2010-05-05T21:37:34Z

Basierend auf ein Kommentar zu meinem ersten Beitrag zum Kabelreceiver HDC-350 habe ich vor einigen Tagen tatsächlich ein Firmware-Update gewagt.

Dabei bin ich wie folgt vorgegangen:

Herunterladen und Entpacken des Firmwarearchivs
Anschließen des Kabelreceivers über die serielle Schnittstelle
Starten des Kabelreceivers über die Fernbedienung
Starten der Datei LoaderHD.exe (Achtung: Unter Windows Vista und Windows 7 muss die Datei ggf. als Administrator ausgeführt werden)
Betätigen der Schaltfläche "Start Update"

Nach kurzer Zeit meldete der Updatevorgang "Update OK" und ich konnte den Kabelreceiver wieder an unseren Fernseher anschliessen.

Auf den ersten Blick konnte ich leider keinerlei Verbesserungen feststellen - was nicht heissen soll, daß sie nicht da wären - und man sieht leider in keinem Menü oder ähnlichen, welche Firmwareversion aktuell installiert ist. Da der Receiver aber tadellos funktioniert hat - auch Senderlisten usw. waren erhalten geblieben - ist dies ein vernachlässigbarer Schönheitsfehler.

Daß ich die neue Firmware tatsächlich installiert hatte, habe ich erst beim Formatieren eines USB-Sticks gemerkt, hier kam tatsächlich eine Meldung, wenn der Vorgang abgeschlossen war.

Was meine ganz persönliche Liste an unterstützen USB-Devices anbelangt, hier hat sich nichts verändert. Nach wie vor werden einige meiner Geräte nicht erkannt, schade!

Ansprechen der seriellen Schnittstelle unter Dynamics AX 2009

2010-06-24T19:47:11Z

Mithilfe der Klasse SerialPorts aus dem .net-Framework kann man unter Dynamics AX 2009 recht bequem auf die serielle Schnittstelle zugreifen. Nachstehend dazu ein kurzes Code-Beispiel, wie man ein Display, wie man es z.B. von Kassensystemen kennt, ansteuern kann.

static void sendText2SerialPort(Args _args)

{

    System.IO.Ports.SerialPort SerialPort;

    str deleteDisplay = num2char(hex2int("0C"));

    ;

    SerialPort = new System.IO.Ports.SerialPort('com4');

    SerialPort.Open(); 

    if(SerialPort.get_IsOpen())

    {

        SerialPort.Write(deleteDisplay); 

        SerialPort.Write('Welcome World!'); 

        SerialPort.Close();

    }

}

Druckoptionen von Berichten k�nnen nicht ge�ndert werden

2010-06-04T18:37:52Z

In Dynamics AX 2009 scheint es einen kleinen Bug zu geben, der bei Reports, welche über eine von RunBaseReport abgeleitete Klasse gestartet werden, dazu führt, daß sich die Druckoptionen nicht ändern lassen.

Um diesen Bug zu umgehen, kann man die Methode dialogUpdatePrinterSettings, wie in nachstehendem Beispiel beschrieben, überschreiben.

public void dialogUpdatePrinterSettings(Dialog dialog)

{

    ;

    // --> (1) Workaround to update printJobSettings and dialog

    this.printJobSettings().unpackPrintJobSettings(this.reportRun().packPrintJobSettings());

    // <-- (1)

    super(dialog);

}

Start- und Enddatum des aktuellen Gesch�ftsjahres ermitteln

2010-05-01T20:02:48Z

Um das Start- und Enddatum des aktuellen Geschäftsjahres zu ermitteln, kann man sich nachstehender Methode bedienen. Diese liefert einen Container zurück, dessen erstes Element das Start- und dessen zweites Element das Enddatum des Geschäftsjahres enthält.

ledgerPeriod::findFiscalYearDates(systemdateget());

Eine von RunBasebatch abgeleitete Klasse ist nicht im Stapel lauff�hig

2010-06-10T20:39:23Z

Vor kurzem hatte ich die Aufgabenstellung, eine Klasse die bereits von RunBase abgeleitet worden war, stapelfähig zu gestalten. So weit so einfach, dachte ich mir und habe in der ClassDeclaration der Klasse extends runBase durch extends runBaseBatch ersetzt. Ich hatte danach zwar den entsprechenden Register im Dialog, die Klasse wurde aber dennoch immer sofort ausgeführt :-(

Nach etwas herumprobieren hatte ich schlussendlich in der Methode getFromDialog den Fehler entdeckt: Diese war so programmiert, daß sie per return true immer true retouniert, das runBaseBatch-Framework benötigt an dieser Stelle allerdings ein return super().

Kleine Ursache, grosse Wirkung.

Shared Project mit X++ erstellen

2010-04-17T21:38:25Z

Nachstehend ein Beispiel, mit dem man in Dynamics AX 2009 per X++ ein Projekt erstellen, und Elemente zu diesem Projekt hinzufügen kann.

static void CreateSharedProject(Args _args)

{

    projectNode         projectNode;

    projectGroupNode    projectGroupNode;

    projectNode         myProjectNode;

    treeNodeName        nameOfProject;

    groupNodeType       groupNodeType;

    treeNodeName        groupNodeName;

    #AOT

    ;

    nameOfProject = 'MyProject';

    // Create shared project

    projectNode    = infolog.projectRootNode();

    projectNode    = projectNode.AOTfindChild('Shared');

    myProjectNode  = projectNode.AOTfindChild(nameOfProject);

    if( !myProjectNode)

    {

        myProjectNode = projectNode.AOTadd(nameOfProject);

        myProjectNode.AOTsave();

    }

    myProjectNode     = myProjectNode.getRunNode();

    // Add groupnode 'Tables'

    groupNodeName = 'Tables';

    projectGroupNode = myProjectNode.AOTfindChild(groupNodeName);

    if( !projectGroupNode)

    {

        myProjectNode.AOTadd(groupNodeName);

        projectGroupNode = myProjectNode.AOTfindChild(groupNodeName);

        projectGroupNode.projectGroupType(GroupNodeType::Tables);

        myProjectNode.AOTsave();

    }

    // Add some tables to groupnode 'Tables'

    if( !projectGroupNode.findGroupMember('SalesTable', UtilElementType::Table))

    {

        projectGroupNode.addUtilNode(UtilElementType::Table, 'SalesTable');

    }

    if( !projectGroupNode.findGroupMember('SalesLine', UtilElementType::Table))

    {

        projectGroupNode.addUtilNode(UtilElementType::Table, 'SalesLine');

    }

    projectGroupNode.AOTsave();

    // Add groupnode 'Forms'

    groupNodeName = 'Forms';

    projectGroupNode = myProjectNode.AOTfindChild(groupNodeName);

    if( !projectGroupNode)

    {

        myProjectNode.AOTadd(groupNodeName);

        projectGroupNode = myProjectNode.AOTfindChild(groupNodeName);

        projectGroupNode.projectGroupType(GroupNodeType::Forms);

        myProjectNode.AOTsave();

    }

    // Add form 'SalesTable' to groupnode 'Forms'

    if( !projectGroupNode.findGroupMember('SalesTable', UtilElementType::Form))

    {

        projectGroupNode.addUtilNode(UtilElementType::Form, 'SalesTable');

    }

    projectGroupNode.AOTsave();

    myProjectNode.AOTsave();

    myProjectNode.AOTrefresh();

    myProjectNode.AOTrun();

}

Das im Beispiel erstellte Projekt sähe wie folgt aus:

Zugriff auf die Zwischenablage per X++

2010-03-26T19:49:10Z

In Dynamics AX kann man selbstverständlich auch auf die Zwischenablage zugreifen, ein kurzes Codebeispiel dazu im folgenden. Funktioniert übrigens zumindest seit Axpata 2.5.

static void useClipboard(Args _args)

{

    textBuffer  textBuffer = new textBuffer();

    ;     

    // Write to clipboard

    textBuffer.appendText('Hello world!');

    textBuffer.toClipboard();

    // Read from clipboard

    textBuffer.fromClipboard();

    info(textBuffer.getText());

}

Palette verlagern per X++

2010-07-31T18:11:11Z

Folgend etwas X++ Code, mit dessen Hilfe man eine Palette verlagern kann, also genau das, was die Schaltfläche "Palette verlagern" in Formular Palette tut.

wmsPalletMove = new wmsPalletMove();

wmsPalletMove.parmWMSPalletId('00000022_117');

wmsPalletMove.parmToInventLocationId('300');

wmsPalletMove.parmToLocationId('01');

if(wmsPalletMove.validate())

   wmsPalletMove.run();

Buchen von Lieferschein und Rechnung per Code

2010-03-19T23:28:24Z

Mit Hilfe der salesFormLetter-Klasse(n) von Dynamics AX ist es möglich, Auftragsbestätigung, Lieferschein und/oder Rechnung für einen Auftrag mit nur wenigen Zeilen Code zu buchen. Nachstehend ein Beispiel, in dem für einen Auftrag alle drei auf einmal gebucht werden:

static void postSalesFormLetter(Args _args)

{

    SalesFormLetter salesFormLetter;

    salesTable      salesTable = salesTable::find('01234');

    ;     

    ttsBegin; 

    // Bestätigung buchen

    salesFormLetter = SalesFormLetter::construct(DocumentStatus::Confirmation); 

    salesFormLetter.update( salesTable,

                            systemDateGet(),

                            SalesUpdate::All,

                            AccountOrder::None,

                            NoYes::No,

                            NoYes::No); 

    // Lieferschein buchen

    salesFormLetter = SalesFormLetter::construct(DocumentStatus::PackingSlip);     

    salesFormLetter.update( salesTable,

                            systemDateGet(),

                            SalesUpdate::All,

                            AccountOrder::None,

                            NoYes::No,

                            NoYes::No);    

    // Rechnung buchen

    salesFormLetter = SalesFormLetter::construct(DocumentStatus::Invoice);     

    salesFormLetter.update( salesTable,

                            systemDateGet(),

                            SalesUpdate::All,

                            AccountOrder::None,

                            NoYes::No,

                            NoYes::No);

    ttsCommit;

}

Getestet in Dynamics AX 2009.

Eintrag "Einstellungen" im Kontextmen� freischalten

2010-02-04T21:00:35Z

Jeder Entwickler kennt ihn und die meisten benutzen ihn auch regelmässig: Den Eintrag "Einstellungen" im Kontextmenü eines Formulares.

Wie man diesen Eintrag über die Berechtigungsverwaltung von Dynamics AX entfernt oder hinzufügt, wusste ich allerdings bis dato nicht. Erst ein Request beim Hersteller, den ein Kollege abgesetzt hat, hat mich auf die richtige Spur gebracht:

Unter Sicherheit / Verwaltung / Sonstiges / Fomular "Personalisierung" muss man die Berechtigung auf mindestens "Bearbeiten" setzen, damit der Eintrag im Kontextmenü aufscheint.

Und jetzt erklär mir mal einer, wie man das selbst finden soll...

Versenden einer Mail an alle Online-Benutzer in Dynamics AX 4.0 und AX 2009

2010-01-19T09:20:33Z

Folgende Schritte sind in Dynamics AX notwendig, um allen Online-Benutzern eine E-Mail zu senden:

Eintragen des zu verwendenden SMTP-Servers unter Verwaltung / Einstellungen / E-Mail-Parameter
Erstellen eines E-Mail-Vorlage vom Typ System unter Grundeinstellungen / Einstellungen / E-Mail-Vorlage
Hier kann der Betreff und der Text der zu versendenden Mail um den Platzhalter %username% erweitert werden.
Versenden der Mail unter Verwaltung / Periodisch / E-Mail-Aussendung

Man kann auch an alle Benutzer einer Installation versenden.

Für technisch Interessierte: Die verantwortliche Klasse ist die SysEmailBroadCast.

Unterschied zwischen update und doUpdate u.�.

2010-02-11T19:31:39Z

Mir persönlich dreht sich ja immer der Magen um, wenn ich in einer Produktivumgebung einen Stückchen Code mit doUpdate() oder Konsorten entdecke, trotzdem verwende ich solcherart Methoden auch gerne für den einen oder anderen Aktualisierungsjob. Wer den Unterschied zwischen dem Aufruf von update() und doUpdate() nicht kennt, kann diesen in der MSDN nachlesen...oder aber auch in der nachstehenden Tabelle.

Methode	Bemerkung
insert vs. doInsert	Bei Verwendung von doInsert wird die insert-Methode der Tabelle nicht aufgerufen
delete vs. doDelete	Bei Verwendung von doDelete wird eine überschriebene delete-Methode der Tabelle nicht aufgerufen, sondern nur die delete-Methode des xRecord. D.h. DeleteActions werden dennoch ausgeführt
update vs. doUpdate	Bei Verwendung von doUpdate wird die update-Methode der Tabelle nicht aufgerufen

Erfahrungsbericht DVB-C-Receiver HDC-350

2010-02-07T13:49:45Z

Vor einiger Zeit wurde unser Kabelanschluß um ein digitales Signal erweitert, als musste schnell ein digitaler HDTV-Kabelreceiver her. Auf Empfehlung unserer Genossenschaft (Sozialbau) wurden wir bei einem Wiener Unternehmen mit dem Kabelreceiver HDC-350 fündig. Erstens war das Gerät mit knapp 100 EUR sehr günstig und stellte über einen USB-Anschluß die Möglichkeit zur Verfügung, einen USB-Speicher anzuschließen und den Receiver als Festplattenrekorder (PVR) zu verwenden.

Leider ist es aber genau diese PVR-Funktion, die bei dem Gerät eher schlecht als recht funktioniert. Zum einen erkennt der USB-Anschluß nur sehr wenige Geräte, eine Positiv- wie Negativ-Liste der von mir getesten Geräte findet ihr im folgenden, zum anderen hat das Gerät die eine oder andere Macke.

Zum Beispiel kommt es immer wieder vor, daß einzelne Aufnahmen nicht mehr abspielbar sind. Diese Aufnahmen verhalten sich so, als würden sie direkt nach dem Start an deren Ende springen. Solche Aufnahmen kann man nur noch löschen.

Findet man aber einen USB-Speicher, der vom Receiver erkannt wird und sieht von den genannten Problemchen ab, funktioniert die Aufnahme dank EPG sehr gut.

Solche Aufnahmen kann man übrigens mit der Software PC2Box am PC archivieren, dies ist aber eine Sache für sich. Ich bin sicherlich technisch nicht unerfahren, aber eine derart rudimentäre Software zum Download anzubieten ist schon fast eine Gemeinheit. Der "normale" PC-User kann mit dieser vermutlich nichts anfangen.

Aber es gibt nicht nur negatives von dem Receiver zu berichten. Das wichtigste ist bei einem solchen Gerät die Bildqualität und die Bedienung. Leider fehlen mir hinsichtlich Bid- und Tonqualität Vergleichsmöglichkeiten, das Bild ist auf jeden Fall besser als Analog ;-)

Zum Ton bliebt zu erwähnen, daß das Gerät über einen optischen Ausgang verfügt, wodurch man es z.B. leicht an ein Heimkinosystem anschließen kann. Über die Fernbedienung kann man rein theroetisch sogar unterschiedliche Tonspuren der jeweils ausgestrahlten Sendung anwählen, seltsamerweise hat dies aber zumindest bei uns keinerlei Effekt. Ich kann aber nicht beurteilen ob das am Gerät liegt, oder an unserem Kabelsignal.

Außerdem liegt dem HDC-350 neben einer Fernbedienung auch ein sog. Fernbedienungsauge dabei, womit es möglich ist den Receiver unsichtbar aufzustellen. Sehr praktisch!

Alles in allem ist mein persönliches Fazit: Kleiner, recht günstiger HDTV-Kabelreceiver, mit dem mit etwas Glück auch Aufnahmen gelingen.

Positivliste

Hitachi Travelstar 40 GB (DK13FA-40) USB-Festplatte 1,8"
Silvercrest USB-Stick 1 GB
Super Talent USB-Stick 4 GB

Negativliste

Sandisk Cruzer Micro USB-Stick 16 GB (U3-Software mit entsprechender Software entfernt)
Samsung HM030GC 2,5" Festplatte 30 GB

Übrigens: Natürlich habe ich mir erlaubt, beim Hersteller nachzufragen, welche Anforderungen an USB-Speicher gestellt werden, damit diese problemlos erkannt werden, leider blieben meine Mails bis dato unbeantwortet...

Zertifizierungspr�fung Microsoft Dynamics AX 2009 Trade & Logistics

2009-12-07T20:44:49Z

Kurzer Eintrag in eigener Sache:

Heute morgen habe ich eine weitere Microsoft Zertifizierungsprüfung - der genaue Titel lautete Microsoft Dynamics AX 2009 Trade & Logistics - erfolgreich abgelegt.

Notizen zur RecId

2010-03-04T19:37:22Z

Die RecId ist die mehr oder weniger eindeutige Kennung eines Datensatzes in Dynamics AX. Mehr oder weniger deshalb, weil es auf die verwendete Version von Dynamics AX bzw. Axapta ankommt:

Version	Bemerkung
3.0	RecId pro Mandant eindeutig (über alle Tabellen)
4.0	RecId pro Tabelle eindeutig (über alle Mandanten) D.h. die selbe RecId kann in zwei oder mehreren Tabellen vorkommen, das ist auch der Grund, warum ein Feld einer Tabelle vom Typ RefRecId als EDT mit einer Relation abgebildet werden muss!
2009	Wie bei Version 4.0

PageFooter sind nicht immer dort, wo sie sein sollten

2009-12-04T17:34:56Z

Ich kenne kein einziges AX-Projekt, in dem nicht zumindest einer der Berichte Auftragsbestätigung, Ausgangslieferschein oder Ausgangsrechnung angepasst worden sind. Und deshalb stolpere ich auch immer wieder über das selbe Problem: Man erweitert einen Bericht (Report) um einen PageFooter, der aber nicht auf jeder Seite angedruckt werden soll.

Die meisten Entwickler lösen dies einfach über die zur Section gehörige Methode executeSection() wobei sie den Aufruf super() ahänigig von irgendwelchen Kriterien ausführen oder nicht. Man findet z.B. solcherart Code des öfteren:

public void executeSection()

{

    ;

    if (salesFormLetterReport.isFooterPresentForCurrentPrintSetting())

    {

        super();

    }

}

Obiger Code ist z.B. aus dem PageFooter namens FooterText aus dem Report SalesConfirm (=Auftragsbestätigung). Hier ist das Ziel der Methode, den sog. Fusszeilentext in dieser Section immer nur dann anzudrucken, wenn dies in den Druckverwaltungseinstellungen für diesen Bericht (unter Debitoren / Einstellungen / Formulareinstellungen / Allgemeines / Druckverwaltung) entsprechend parametriert ist.

Dynamics AX ist nun aber leider so dumm, daß es sich - obwohl hier vielleicht gar kein Text parametriert ist - dennoch am Bericht den entsprechenden Platz reserviert. D.h. beim Ausdrucken des entsprechenden Dokumentes "rutschen" evtl. andere PageFooter zu weit hinauf und man verliert wertvollen Platz für Auftragspositionen o.ä.

Einfach umgehen kann man dieses Fehlverhalten über das deaktivieren der entsprechenden Section in der fetch()-Methode:

boolean  fetch()

{

    ...
    if ( !salesFormLetterReport.isFooterPresentForCurrentPrintSetting())

    {

        element.disableSection(FooterText); // FooterText ist der Name der Section

    }
    ...

}

Es gibt natürlich auch noch andere Wege. Beispielsweise könnte man die Höhe der ganzen Section über

FooterText.height(0, units::mm);

zurücksetzen. Es kommt immer auf die jeweilige Anforderung und den Aufbau des Reports an, für welche Variante man sich entscheidet.

Wichtig ist nur, immer super() in der exceuteSection() aufrufen!

startUpCmd=compileAll

2010-02-25T21:37:42Z

Mit Hilfe dieses Parameters von Dynamics AX ist es möglich, eine vollständige Kompilierung der Applikation zu initieren. Dabei sind folgende drei Varainten verfügbar:

1.) Kompiliert die Applikation und aktualisiert - soferne dies in den Benutzeroptionen so festgelegt ist - auch die Querverweise

"C:\Programme\Microsoft Dynamics AX\50\Client\Bin\Ax32.exe"
-startUpCmd=compileAll

2.) Kompilieren der Applikation inkl. Aktualisierung der Querverweise

"C:\Programme\Microsoft Dynamics AX\50\Client\Bin\Ax32.exe"
-startUpCmd==compileAll_+

3.) Kompiliert die Applikation ohne die Querverweise zu aktualisieren

"C:\Programme\Microsoft Dynamics AX\50\Client\Bin\Ax32.exe"
-startUpCmd==compileAll_-

In allen drei Fällen wird übrigens - zumindest in AX 2009 - eine Level 4-Kompilierung initiert, d.h. die Applikation wird auch hinsichtlich Best-Practice-Abweichungen geprüft.

Das Ergebnis der Kompilierung ist anschließend in der Datei AxCompileAll.html im Log-Verzeichnis des Clients zu finden.